Função MÉDIA.SE
Devolve a média aritmética de todas as células do intervalo que cumprem uma condição. A função MÉDIA.SE soma todos os valores que cumprem a condição e divide essa soma pelo número de valores selecionados.
=AVERAGEIF(Range; Criterion [; Average_Range ])
intervalo - argumento obrigatório. Consiste numa ou mais células cuja média pretende calcular, incluindo números ou nomes, matrizes ou referências que contenham números.
A pesquisa suporta caracteres curinga ou expressões regulares. Com as expressões regulares ativadas, pode introduzir «all.*», por exemplo, para encontrar a primeira ocorrência de «all» seguida de quaisquer caracteres. Se pretender pesquisar um texto que também seja uma expressão regular, deve preceder cada metacaractere ou operador de expressão regular com um caractere "\" ou colocar o texto entre \Q...\E. Pode ativar ou desativar a avaliação automática de curingas ou expressões regulares em .
Ao usar funções onde um ou mais argumentos são textos que representem uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Contudo, se mudar de configuração regional e o separador decimal não for o ponto, a expressão regular será utilizada. Para forçar a avaliação da expressão regular em vez de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número como, por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".
intervalo_média - argumento opcional. É o conjunto de células do qual pretende obter a média.
If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.
Se uma célula do intervalo estiver vazia ou contiver texto, a função MÉDIA.SE ignora essa célula.
Se todo o intervalo estiver vazio, apenas contiver texto, ou nenhum dos valores cumpre os critérios (ou uma combinação de qualquer uma das anteriores), a função devolve o erro #DIV/0!.
Considere a seguinte tabela
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Nome do produto |
Sales |
Revenue |
|
2 |
pencil |
20 |
65 |
|
3 |
pen |
35 |
85 |
|
4 |
caderno |
20 |
190 |
|
5 |
book |
17 |
180 |
|
6 |
pencil-case |
not |
not |
In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.
Utilização
=MÉDIA.SE(B2:B6;"<35")
Calcula a média dos valores no intervalo B2:B6 que sejam inferiores a 35. Devolve 19, uma vez que a segunda linha não participa no cálculo.
=MÉDIA.SE(B2:B6;"<"&MÁXIMO(B2:B6))
Calcula a média dos valores do intervalo B2:B6 que sejam inferiores ao valor máximo do intervalo. Devolve 19, uma vez que o maior valor do intervalo (segunda linha) não participa no cálculo.
=MÉDIA.SE(B2:B6;">"&MENOR(B2:B6;1))
Calcula a média dos valores no intervalo B2:B6 que sejam superiores ao menor valor do intervalo. Devolve 25, uma vez que o menor valor (segunda linha) não participa no cálculo.
Utilização de intervalo_média
=MÉDIA.SE(B2:B6;"<35";C2:C6)
A função pesquisa que valores do intervalo B2:B6 são inferiores a a 35 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 145, uma vez que a segunda linha não participa no cálculo.
=MÉDIA.SE(B2:B6;">"&MÍNIMO(B2:B6);C2:C6)
A função pesquisa que valores do intervalo B2:B6 são superiores ao menor valor do intervalo B2:B6 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 113,3, uma vez que a quarta linha (linha em que está o menor valor) não participa no cálculo.
=MÉDIA.SE(B2:B6;"<"&MAIOR(B2:B6;2);C2:C6)
A função pesquisa que valores do intervalo B2:B6 são inferiores ao segundo maior valor do intervalo B2:B6 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 180, uma vez que apenas a quarta linha participa no cálculo.
Utilizar expressões regulares
=MÉDIA.SE(A2:A6;"pen";B2:B6)
A função procura as células do intervalo A2:A6 que apenas contenham a palavra “pen” e calcula a média dos valores correspondentes no intervalo B2:B6. Devolve 35, porque apenas a segunda linha participa nos cálculos.. A procura é efetuada no intervalo A2:A6, mas os valores devolvidos pertencem ao intervalo B2:B6.
=MÉDIA.SE(A2:A6;"pen.*";B2:B6)
A função procura as células do intervalo A2:A6 que se iniciem com “pen” e que terminem com quaisquer outros caracteres, calculando a média dos correspondentes valores no intervalo B2:B6. Devolve 27,5 porque agora também “pencil” satisfaz a condição, o que faz com que a segunda linha também entre no cálculo.
=MÉDIA.SE(A2:A6;".*book.*";B2:B6)
A função procura as células do intervalo A2:A6 que iniciem com “book” e que terminem com qualquer outro carácter e calcula a média dos valores correspondentes no intervalo B2:B6. Devolve 18,5 porque apenas a terceira e a quarta linha participam no cálculo.
Referência a uma célula como critério
Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência à célula como condição da função MÉDIA.SE.
=MÉDIA.SE(A2:A6;".*"&E2&".*";B2:B6)
A função procura as células do intervalo A2:A6 que contenham a combinação de caracteres especificados em E2 (iniciando ou terminando com outras combinações de caracteres) e calcula a média dos valores correspondentes do intervalo B2:B6. Se E2 = book, a função devolve 18,5.
=MÉDIA.SE(B2:B6;"<"&E2;C2:C6)
A função procura que células do intervalo A2:A6 possuem um valor inferior ao especificado em E2 e calcula a média dos valores correspondentes no intervalo B2:B6. Se E2=35, a função devolve 145.
Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).
